- WinPerf improvements
[public/netxms.git] / configure.ac
1 # $Id: configure.ac,v 1.27 2004-10-05 15:57:13 victor Exp $
2 #
3 # Process this file with autoconf to produce a configure script.
4 #
5
6 AC_INIT([NetXMS], [0.1.4], [NetXMS Team <bugs@netxms.org>])
7 AC_CONFIG_AUX_DIR([config])
8 AM_CONFIG_HEADER([config.h])
9 AM_INIT_AUTOMAKE
10
11 # --------------------------------------------------------------------------
12 # misc
13
14 AC_ARG_VAR(PERL,local path to the perl interpreter)
15 perl_possible_path="/usr/bin:/usr/local/bin:/bin:/opt/perl/bin:/opt/perl/usr/bin:/opt/perl/usr/local/bin"
16 AC_PATH_PROG(PERL,perl,/usr/bin/env perl,$perl_possible_path)
17
18 if test -d /usr/local/include; then
19 CFLAGS="$CFLAGS -I/usr/local/include"
20 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
21 fi
22
23 if test -d /usr/kerberos/include; then
24 CFLAGS="$CFLAGS -I/usr/kerberos/include"
25 CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
26 fi
27
28 if test -d /usr/local/ssl/include; then
29 CFLAGS="$CFLAGS -I/usr/local/ssl/include"
30 CPPFLAGS="$CPPFLAGS -I/usr/local/ssl/include"
31 fi
32
33 if test -d /usr/local/lib; then
34 LDFLAGS="$LDFLAGS -L/usr/local/lib"
35 fi
36
37 # --------------------------------------------------------------------------
38 # command line options
39
40 AC_ARG_WITH(mysql,
41 [AS_HELP_STRING(--with-mysql,enable mysql backend)],
42 [ if test "x$withval" != "xno" ; then
43 if test "x$withval" != "x" && test "x$withval" != "xyes" ; then
44 LD_RUN_PATH="${withval}/lib${LD_RUN_PATH:+:}${LD_RUN_PATH}"
45 LDFLAGS="$LDFLAGS -L${withval}/lib -L${withval}/lib/mysql -L${withval}/mysql/lib"
46 CPPFLAGS="$CPPFLAGS -I${withval}/include -I${withval}/include/mysql -I${withval}/mysql/include"
47 else
48 LD_RUN_PATH="/usr/local/mysql/lib:/usr/local/mysql/lib/mysql:/usr/lib/mysql:/usr/mysql/lib:/usr/mysql/lib/mysql:/usr/local/lib/mysql:${LD_RUN_PATH:+:}${LD_RUN_PATH}"
49 LDFLAGS="$LDFLAGS -L/usr/local/mysql/lib -L/usr/lib/mysql -L/usr/mysql/lib -L/usr/local/lib/mysql -L/usr/local/mysql/lib/mysql -L/usr/mysql/lib/mysql"
50 CPPFLAGS="$CPPFLAGS -I/usr/local/mysql/include -I/usr/include/mysql -I/usr/mysql/include -I/usr/local/include/mysql -I/usr/local/mysql/include/mysql -I/usr/mysql/include/mysql"
51 fi
52 AC_CHECK_LIB(m, floor)
53 AC_CHECK_LIB(z, gzclose)
54 with_mysql="yes"
55 AC_DEFINE(WITH_MYSQL,,[with mysql])
56 DB_DRIVERS="$DB_DRIVERS mysql"
57 AC_CHECK_LIB(mysqlclient, mysql_init, ,
58 [AC_MSG_ERROR(libmysqlclient is needed for MySQL support)])
59 AC_MSG_CHECKING(whether mysql clients can run)
60 AC_RUN_IFELSE([AC_LANG_SOURCE([[
61 #include <stdio.h>
62 #include <mysql.h>
63 int main(void)
64 {
65 MYSQL *a = mysql_init(NULL);
66 return 0;
67 }
68 ]])],[],[
69 AC_MSG_RESULT(no)
70 AC_MSG_ERROR(Your MySQL client libraries aren't properly installed)
71 ],[])
72 AC_MSG_RESULT(yes)
73 AC_CHECK_FUNCS(mysql_real_escape_string)
74 fi ])
75
76 AC_ARG_WITH(pgsql,
77 [AS_HELP_STRING(--with-pgsql,enable postgres backend)],
78 [ if test "x$withval" != "xno" ; then
79 if test "x$withval" != "x" && test "x$withval" != "xyes" ; then
80 LD_RUN_PATH="${withval}/lib${LD_RUN_PATH:+:}${LD_RUN_PATH}"
81 LDFLAGS="$LDFLAGS -L${withval}/lib -L${withval}/lib/pgsql -L${withval}/lib/postgresql -L${withval}/pgsql/lib -L${withval}/postgresql/lib"
82 CPPFLAGS="$CPPFLAGS -I${withval}/include -I${withval}/include/pgsql -I${withval}/include/postgresql -I${withval}/pgsql/include -I${withval}/postgresql/include"
83 else
84 LD_RUN_PATH="/usr/local/pgsql/lib:/usr/local/pgsql/lib/pgsql:/usr/lib/pgsql:/usr/pgsql/lib:/usr/pgsql/lib/pgsql:/usr/local/lib/pgsql:/usr/local/postgresql/lib:/usr/local/postgresql/lib/postgresql:/usr/lib/postgresql:/usr/postgresql/lib:/usr/postgresql/lib/postgresql:/usr/local/lib/postgresql:${LD_RUN_PATH:+:}${LD_RUN_PATH}"
85 LDFLAGS="$LDFLAGS -L/usr/local/pgsql/lib -L/usr/lib/pgsql -L/usr/pgsql/lib -L/usr/local/lib/pgsql -L/usr/local/pgsql/lib/pgsql -L/usr/pgsql/lib/pgsql -L/usr/local/postgresql/lib -L/usr/lib/postgresql -L/usr/postgresql/lib -L/usr/local/lib/postgresql -L/usr/local/postgresql/lib/postgresql -L/usr/postgresql/lib/postgresql"
86 CPPFLAGS="$CPPFLAGS -I/usr/local/pgsql/include -I/usr/include/pgsql -I/usr/pgsql/include -I/usr/local/include/pgsql -I/usr/local/pgsql/include/pgsql -I/usr/pgsql/include/pgsql -I/usr/local/postgresql/include -I/usr/include/postgresql -I/usr/postgresql/include -I/usr/local/include/postgresql -I/usr/local/postgresql/include/postgresql -I/usr/postgresql/include/postgresql"
87 fi
88 AC_CHECK_LIB(m, floor)
89 AC_CHECK_LIB(z, gzclose)
90 with_pgsql="yes"
91 DB_DRIVERS="$DB_DRIVERS pgsql"
92 AC_DEFINE(WITH_PGSQL,,[with pgsql])
93 AC_CHECK_LIB(pq, PQconnectdb, ,
94 [AC_MSG_ERROR(libpq is needed for PostgreSQL support)])
95 AC_MSG_CHECKING(whether postgresql clients can run)
96 AC_RUN_IFELSE([AC_LANG_SOURCE([[
97 #include <stdio.h>
98 #include <libpq-fe.h>
99 int main(void)
100 {
101 PGconn *a = PQconnectdb("");
102 return 0;
103 }
104 ]])],[],[
105 AC_MSG_RESULT(no)
106 AC_MSG_ERROR(Your PostgreSQL client libraries aren't properly installed)
107 ],[])
108 AC_MSG_RESULT(yes)
109 fi ])
110
111 AC_SUBST(DB_DRIVERS)
112
113
114 # --------------------------------------------------------------------------
115 # checks for programs.
116
117 AC_PROG_CC
118 AC_PROG_CPP
119 AC_PROG_INSTALL
120
121 AC_LIBTOOL_DLOPEN
122 AC_PROG_LIBTOOL
123
124 # --------------------------------------------------------------------------
125 # checks for libs.
126
127 #AC_CHECK_LIB([socket], [socket])
128 #AC_CHECK_LIB([nsl], [gethostbyname])
129
130 AC_CHECK_LIB(crypto, DH_new)
131 AC_CHECK_LIB(ssl, SSL_accept)
132 AC_CHECK_LIB(termcap, tgetstr, [], [AC_CHECK_LIB(ncurses, tgetstr, [], AC_CHECK_LIB(curses, tgetstr))])
133 AC_CHECK_LIB(readline, readline)
134 AC_CHECK_LIB(socket, if_nameindex)
135
136 # --------------------------------------------------------------------------
137 # checks for headers.
138
139 AC_HEADER_STDC
140 AC_HEADER_STAT
141 AC_HEADER_TIME
142 AC_CHECK_HEADERS([sys/int_types.h])
143 AC_CHECK_HEADERS([arpa/inet.h netdb.h netinet/in.h sys/socket.h])
144 AC_CHECK_HEADERS([sys/ioctl.h sys/sockio.h])
145 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h])
146 AC_CHECK_HEADERS([openssl/ssl.h])
147 AC_CHECK_HEADERS([readline/readline.h])
148 AC_CHECK_HEADERS([byteswap.h])
149 AC_CHECK_HEADERS([sys/mman.h])
150 AC_CHECK_HEADERS([sys/utsname.h])
151
152 if test "x$ac_cv_header_openssl_ssl_h" != "xyes" ; then
153 AC_MSG_ERROR(OpenSSL headers not found.)
154 fi
155
156 # --------------------------------------------------------------------------
157 # types
158 AC_CHECK_SIZEOF(short)
159 AC_CHECK_SIZEOF(int)
160 AC_CHECK_SIZEOF(long)
161 AC_CHECK_SIZEOF(long long)
162
163 AC_TYPE_PID_T
164 AC_TYPE_SIGNAL
165 AC_TYPE_SIZE_T
166 AC_STRUCT_TIMEZONE
167
168 AC_CHECK_TYPES([int64_t, uint64_t, u_int64_t])
169 AC_CHECK_TYPES([off_t])
170
171 # --------------------------------------------------------------------------
172 # C/CPP caps
173
174 AC_PROG_GCC_TRADITIONAL
175 AC_C_CONST
176 AC_C_BIGENDIAN
177
178 # --------------------------------------------------------------------------
179 # macros
180
181 AC_CHECK_DECLS([__bswap_64],,,[
182 #if HAVE_BYTESWAP_H
183 #include <byteswap.h>
184 #endif
185 ])
186 AC_CHECK_DECLS([SIOCGIFADDR, SIOCGIFNETMASK, SIOCGIFHWADDR],,,[
187 #if HAVE_SYS_IOCTL_H
188 #include <sys/ioctl.h>
189 #endif
190 #if HAVE_SYS_SOCKIO_H
191 #include <sys/sockio.h>
192 #endif
193 ])
194
195 # --------------------------------------------------------------------------
196 # library functions
197
198 AC_FUNC_ERROR_AT_LINE
199 AC_FUNC_MALLOC
200 AC_FUNC_MEMCMP
201 AC_FUNC_REALLOC
202 AC_FUNC_SELECT_ARGTYPES
203 AC_FUNC_STRFTIME
204 AC_FUNC_STRTOD
205 AC_FUNC_VPRINTF
206
207 AC_CHECK_FUNCS([gettimeofday memmove memset strchr strcspn strdup strerror])
208 AC_CHECK_FUNCS([strrchr strtol strtoul strtoll strtoull])
209 AC_CHECK_FUNCS([if_nametoindex daemon mmap strerror_r])
210
211 # --------------------------------------------------------------------------
212 # UNICODE support
213
214 AC_CHECK_HEADERS([wchar.h])
215 AC_CHECK_TYPES([wchar_t])
216 AC_CHECK_FUNCS([wctomb mbtowc wcslen])
217
218
219 # sockets/resolver (probably for solaris)
220 AC_CHECK_FUNC(connect, , [AC_CHECK_LIB(socket, connect)])
221 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(resolv, gethostbyname)])
222 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(nsl, gethostbyname)])
223
224 if test "x$ac_cv_lib_nsl_gethostbyname" != "xyes" && test "x$ac_cv_func_gethostbyname" != "xyes" ; then
225 AC_CHECK_FUNC(gethostbyname, , [AC_CHECK_LIB(socket, gethostbyname)])
226 fi
227
228 if test "$ac_cv_lib_nsl_gethostbyname" = "$ac_cv_func_gethostbyname" ; then
229 AC_MSG_CHECKING([if we can include libnsl + libsocket])
230 LIBS="-lnsl -lsocket $LIBS"
231 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[(void) gethostbyname]])],[my_ac_link_result=yes],[my_ac_link_result=no ])
232 if test "$my_ac_link_result" = "no" ; then
233 AC_MSG_RESULT([failure])
234 AC_MSG_ERROR([unable to use gethostbyname()])
235 else
236 AC_MSG_RESULT([success])
237 fi
238 fi
239
240 # posix threads
241 AC_CHECK_HEADER(pthread.h,,AC_MSG_ERROR([*** POSIX thread support not installed - please install first ***]))
242
243 PTHREAD_LIBS=error
244 AC_MSG_CHECKING(for old style FreeBSD -pthread flag)
245 AC_EGREP_CPP(yes,
246 [#if (defined(__FreeBSD_cc_version) && __FreeBSD_cc_version <= 500001) || defined(__OpenBSD__)
247 yes
248 #endif
249 ], AC_MSG_RESULT(yes)
250 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE" PTHREAD_LIBS="-pthread",
251 AC_MSG_RESULT(no))
252 if test "x$PTHREAD_LIBS" = xerror; then
253 AC_CHECK_LIB(pthread, pthread_attr_init,
254 PTHREAD_LIBS="-lpthread")
255 fi
256 if test "x$PTHREAD_LIBS" = xerror; then
257 AC_CHECK_LIB(pthreads, pthread_attr_init,
258 PTHREAD_LIBS="-lpthreads")
259 fi
260 if test "x$PTHREAD_LIBS" = xerror; then
261 AC_CHECK_LIB(c_r, pthread_attr_init,
262 PTHREAD_LIBS="-lc_r")
263 fi
264 if test "x$PTHREAD_LIBS" = xerror; then
265 AC_CHECK_FUNC(pthread_attr_init,
266 PTHREAD_LIBS="")
267 fi
268 if test "x$PTHREAD_LIBS" = xerror; then
269 AC_MSG_ERROR(*** Unable to locate working posix thread library ***)
270 fi
271 AC_SUBST(PTHREAD_LIBS)
272
273 # Extensions to posix threads
274 AC_CHECK_FUNCS([pthread_cond_reltimedwait_np])
275
276 # --------------------------------------------------------------------------
277 # OS type
278 case `uname -s` in
279 Linux)
280 SUBAGENT_DIRS="linux"
281 ;;
282 FreeBSD)
283 SUBAGENT_DIRS="freebsd"
284 ;;
285 SunOS)
286 SUBAGENT_DIRS="sunos"
287 ;;
288 *)
289 # unknown
290 ;;
291 esac
292 AC_SUBST(SUBAGENT_DIRS)
293
294 # --------------------------------------------------------------------------
295
296 # shared libs versions
297 #
298 # versioning scheme: current:revision:age
299 #
300 # current
301 # The number of the current interface exported by the library. A current
302 # value of `0', means that you are calling the interface exported by this
303 # library interface 0.
304 #
305 # revision
306 # The implementation number of the most recent interface exported by this
307 # library. In this case, a revision value of `0' means that this is the
308 # first implementation of the interface.
309 # If the next release of this library exports the same interface, but has a
310 # different implementation (perhaps some bugs have been fixed), the revision
311 # number will be higher, but current number will be the same. In that case,
312 # when given a choice, the library with the highest revision will always
313 # be used by the runtime loader.
314 #
315 # age
316 # The number of previous additional interfaces supported by this library.
317 # If age were `2', then this library can be linked into executables which
318 # were built with a release of this library that exported the current
319 # interface number, current, or any of the previous two interfaces.
320 # By definition age must be less than or equal to current. At the outset,
321 # only the first ever interface is implemented, so age can only be `0'.
322 #
323 #
324 #
325
326 LIBNETXMS_LIBRARY_VERSION=0:1:0
327 LIBNXCSCP_LIBRARY_VERSION=0:1:0
328 LIBNXSRV_LIBRARY_VERSION=0:1:0
329 DBDRV_LIBRARY_VERSION=0:1:0
330 AC_SUBST(LIBNETXMS_LIBRARY_VERSION)
331 AC_SUBST(LIBNXCSCP_LIBRARY_VERSION)
332 AC_SUBST(LIBNXSRV_LIBRARY_VERSION)
333 AC_SUBST(DBDRV_LIBRARY_VERSION)
334
335 # --------------------------------------------------------------------------
336
337 AC_CONFIG_FILES([
338 Makefile
339 README
340 doc/Makefile
341 m4/Makefile
342 sql/Makefile
343 include/Makefile
344 src/Makefile
345 src/libnetxms/Makefile
346 src/libnxcscp/Makefile
347 src/libnxcl/Makefile
348 src/server/Makefile
349 src/server/libnxsrv/Makefile
350 src/server/core/Makefile
351 src/server/tools/Makefile
352 src/server/tools/nxget/Makefile
353 src/server/tools/nxaction/Makefile
354 src/server/dbdrv/Makefile
355 src/server/dbdrv/mysql/Makefile
356 src/server/dbdrv/pgsql/Makefile
357 src/agent/Makefile
358 src/agent/core/Makefile
359 src/agent/subagents/Makefile
360 src/agent/subagents/skeleton/Makefile
361 src/agent/subagents/linux/Makefile
362 ])
363
364 AC_OUTPUT